source: stylesheets/patcheslist.xsl @ 7860781

Last change on this file since 7860781 was 7860781, checked in by Jim Gifford <clfs@…>, 16 years ago

r3374@server (orig r1557): manuel | 2006-05-10 15:51:37 -0700
Updated stylesheets to match current LFS features.

  • Property mode set to 100644
File size: 2.4 KB
Line 
1<?xml version='1.0' encoding='ISO-8859-1'?>
2<!DOCTYPE xsl:stylesheet [
3 <!ENTITY % general-entities SYSTEM "../general.ent">
4  %general-entities;
5]>
6
7<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
8                version="1.0">
9
10  <xsl:output method="text"/>
11
12    <!-- Allow select the dest dir at runtime -->
13  <xsl:param name="dest.dir">
14    <xsl:value-of select="concat('/home/httpd/', substring-after('&patches-root;', 'http://'))"/>
15  </xsl:param>
16
17  <xsl:template match="/">
18    <xsl:text>#! /bin/bash
19
20function copy
21{
22  cp $1 $2 >>copyerrs 2>&amp;1
23}
24
25umask 002 &#x0a;&#x0a;</xsl:text>
26               
27      <!-- Create dest.dir if it don't exist -->
28    <xsl:text>install -d -m 775 -g lfswww </xsl:text>
29    <xsl:value-of select="$dest.dir"/>
30    <xsl:text> &amp;&amp;&#x0a;</xsl:text>
31    <xsl:text>cd </xsl:text>
32    <xsl:value-of select="$dest.dir"/>
33    <xsl:text> &amp;&amp;&#x0a;&#x0a;</xsl:text>
34      <!-- Remove old patches -->
35    <xsl:text>rm -f *.patch copyerrs &amp;&amp; &#x0a;&#x0a;</xsl:text>
36    <xsl:apply-templates/>
37      <!-- Ensure correct owneship -->
38    <xsl:text>&#x0a;chgrp lfswww *.patch &amp;&amp;&#x0a;</xsl:text>
39    <xsl:text>
40if [ `wc -l copyerrs | sed 's/ *//' | cut -f1 -d' '` -gt 0 ]; then
41  mail -s "Missing LFS patches" lfs-book@linuxfromscratch.org &lt; copyerrs
42fi&#x0a;&#x0a;</xsl:text>
43         
44    <xsl:text>exit&#x0a;</xsl:text>
45  </xsl:template>
46
47  <xsl:template match="//text()"/>
48
49  <xsl:template match="//ulink">
50      <!-- Match only local patches links and skip duplicated URLs splitted for PDF output-->
51    <xsl:if test="contains(@url, '.patch') and contains(@url, '&patches-root;')
52            and not(ancestor-or-self::*/@condition = 'pdf')">
53      <xsl:variable name="patch.name" select="substring-after(@url, '&patches-root;')"/>
54      <xsl:variable name="cut" 
55              select="translate(substring-after($patch.name, '-'), '0123456789', '0000000000')"/>
56      <xsl:variable name="patch.name2">
57        <xsl:value-of select="substring-before($patch.name, '-')"/>
58        <xsl:text>-</xsl:text>
59        <xsl:value-of select="$cut"/>
60      </xsl:variable>
61      <xsl:text>copy /home/httpd/www.linuxfromscratch.org/patches/downloads/</xsl:text>
62          <xsl:value-of select="substring-before($patch.name2, '-0')"/>
63      <xsl:text>/</xsl:text>
64      <xsl:value-of select="$patch.name"/>
65      <xsl:text> . &#x0a;</xsl:text>
66    </xsl:if>
67  </xsl:template>
68
69</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.