Context Navigation

source: clfs-sysroot/BOOK/stylesheets/lfs-xsl/xhtml/lfs-index.xsl @ a18aefd

Last change on this file since a18aefd was a18aefd, checked in by Manuel Canales Esparcia <manuel@…>, 17 years ago
Added lfs-xsl stylesheets.
Property mode set to `100644`
File size: 16.3 KB

Line
1	<?xml version='1.0' encoding='ISO-8859-1'?>
2
3	<!--
4	$LastChangedBy$
5	$Date$
6	-->
7
8	<!DOCTYPE xsl:stylesheet [
9	<!ENTITY lowercase "'AaÀàÁáÂâÃãÄäÅåĀāĂăĄąǍǎǞǟǠǡǺǻȀȁȂȃȦȧḀḁẚẠạẢảẤấẦầẨẩẪẫẬậẮắẰằẲẳẴẵẶặBbƀƁɓƂƃḂḃḄḅḆḇCcÇçĆćĈĉĊċČčƇƈɕḈḉDdĎďĐđƊɗƋƌǅǲȡɖḊḋḌḍḎḏḐḑḒḓEeÈèÉéÊêËëĒēĔĕĖėĘęĚěȄȅȆȇȨȩḔḕḖḗḘḙḚḛḜḝẸẹẺẻẼẽẾếỀềỂểỄễỆệFfƑƒḞḟGgĜĝĞğĠġĢģƓɠǤǥǦǧǴǵḠḡHhĤĥĦħȞȟɦḢḣḤḥḦḧḨḩḪḫẖIiÌìÍíÎîÏïĨĩĪīĬĭĮįİƗɨǏǐȈȉȊȋḬḭḮḯỈỉỊịJjĴĵǰʝKkĶķƘƙǨǩḰḱḲḳḴḵLlĹĺĻļĽľĿŀŁłƚǈȴɫɬɭḶḷḸḹḺḻḼḽMmɱḾḿṀṁṂṃNnÑñŃńŅņŇňƝɲƞȠǋǸǹȵɳṄṅṆṇṈṉṊṋOoÒòÓóÔôÕõÖöØøŌōŎŏŐőƟƠơǑǒǪǫǬǭǾǿȌȍȎȏȪȫȬȭȮȯȰȱṌṍṎṏṐṑṒṓỌọỎỏỐốỒồỔổỖỗỘộỚớỜờỞởỠỡỢợPpƤƥṔṕṖṗQqʠRrŔŕŖŗŘřȐȑȒȓɼɽɾṘṙṚṛṜṝṞṟSsŚśŜŝŞşŠšȘșʂṠṡṢṣṤṥṦṧṨṩTtŢţŤťŦŧƫƬƭƮʈȚțȶṪṫṬṭṮṯṰṱẗUuÙùÚúÛûÜüŨũŪūŬŭŮůŰűŲųƯưǓǔǕǖǗǘǙǚǛǜȔȕȖȗṲṳṴṵṶṷṸṹṺṻỤụỦủỨứỪừỬửỮữỰựVvƲʋṼṽṾṿWwŴŵẀẁẂẃẄẅẆẇẈẉẘXxẊẋẌẍYyÝýÿŸŶŷƳƴȲȳẎẏẙỲỳỴỵỶỷỸỹZzŹźŻżŽžƵƶȤȥʐʑẐẑẒẓẔẕẕ'">
10	<!ENTITY uppercase "'AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAABBBBBBBBBBBBBCCCCCCCCCCCCCCCCCDDDDDDDDDDDDDDDDDDDDDDDDEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEFFFFFFGGGGGGGGGGGGGGGGGGGGHHHHHHHHHHHHHHHHHHHHIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIJJJJJJKKKKKKKKKKKKKKLLLLLLLLLLLLLLLLLLLLLLLLLLMMMMMMMMMNNNNNNNNNNNNNNNNNNNNNNNNNNNOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOOPPPPPPPPQQQRRRRRRRRRRRRRRRRRRRRRRRSSSSSSSSSSSSSSSSSSSSSSSTTTTTTTTTTTTTTTTTTTTTTTTTUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUVVVVVVVVWWWWWWWWWWWWWWWXXXXXXYYYYYYYYYYYYYYYYYYYYYYYZZZZZZZZZZZZZZZZZZZZZ'">
11	<!ENTITY primary 'normalize-space(concat(primary/@sortas, primary[not(@sortas) or @sortas = ""]))'>
12	<!ENTITY secondary 'normalize-space(concat(secondary/@sortas, secondary[not(@sortas) or @sortas = ""]))'>
13	<!ENTITY scope "count(ancestor::node()\|$scope) = count(ancestor::node())">
14	<!ENTITY section "(ancestor-or-self::set \|ancestor-or-self::book \|ancestor-or-self::part \|ancestor-or-self::reference \|ancestor-or-self::partintro \|ancestor-or-self::chapter \|ancestor-or-self::appendix \|ancestor-or-self::preface \|ancestor-or-self::article \|ancestor-or-self::section \|ancestor-or-self::sect1 \|ancestor-or-self::sect2 \|ancestor-or-self::sect3 \|ancestor-or-self::sect4 \|ancestor-or-self::sect5 \|ancestor-or-self::refentry \|ancestor-or-self::refsect1 \|ancestor-or-self::refsect2 \|ancestor-or-self::refsect3 \|ancestor-or-self::simplesect \|ancestor-or-self::bibliography \|ancestor-or-self::glossary \|ancestor-or-self::index \|ancestor-or-self::webpage)[last()]">
15	<!ENTITY section.id "generate-id(&section;)">
16	<!ENTITY sep '" "'>
17	]>
18
19	<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
20	xmlns="http://www.w3.org/1999/xhtml"
21	version="1.0">
22
23	<!-- This stylesheet controls how the Index is generated.
24	Due how they are created, the original XHTML stylesheets don't make
25	use of the entities from {docbook-xsl}/common/entities.ent.
26	We add the relevant ones in the DOCTYPE to have more readable templates.
27	Also, we remove support for @role and @type based Index due that it is
28	broken when used with @zone based cross-references. -->
29
30	<!-- The file name of the Index page.
31	There is no upstream template with match="index", only a global
32	match="*", thus the next template is enought to force the Index
33	filename. -->
34	<xsl:template match="index" mode="recursive-chunk-filename">
35	<xsl:text>longindex.html</xsl:text>
36	</xsl:template>
37
38	<!-- The Index title in the longindex.html page:
39	Removed a lot of code not useful for us.
40	Forced h1 title size. -->
41	<!-- The original template is in {docbook-xsl}/xhtml/titlepage.templates.xsl -->
42	<xsl:template name="index.titlepage">
43	<h1 class="index">
44	<xsl:call-template name="gentext">
45	<xsl:with-param name="key" select="$index-title"/>
46	</xsl:call-template>
47	</h1>
48	</xsl:template>
49
50	<!--Divisions:
51	Translate alphabetical divisons titles to by-type titles.
52	Added gentext support to divisions titles.
53	Using h2 for divisions titles.
54	Changed output from dl format to ul format. -->
55	<!-- The original template is in {docbook-xsl}/xhtml/autoidx.xsl -->
56	<xsl:template match="indexterm" mode="index-div-basic">
57	<xsl:param name="scope" select="."/>
58	<xsl:variable name="key" select="translate(substring(&primary;, 1, 1),&lowercase;,&uppercase;)"/>
59	<xsl:variable name="divtitle" select="translate($key, &lowercase;, &uppercase;)"/>
60	<!-- Make sure that we don't generate a div if there are no terms in scope -->
61	<xsl:if test="key('letter', $key)[&scope;] [count(.\|key('primary', &primary;)[&scope;][1]) = 1]">
62	<xsl:if test="contains(concat(&lowercase;, &uppercase;), $key)">
63	<h2>
64	<xsl:choose>
65	<xsl:when test="$divtitle = 'A'">
66	<a id="package-index" name="package-index"/>
67	<xsl:call-template name="gentext">
68	<xsl:with-param name="key">Packages</xsl:with-param>
69	</xsl:call-template>
70	</xsl:when>
71	<xsl:when test="$divtitle = 'B'">
72	<a id="program-index" name="program-index"/>
73	<xsl:call-template name="gentext">
74	<xsl:with-param name="key">Programs</xsl:with-param>
75	</xsl:call-template>
76	</xsl:when>
77	<xsl:when test="$divtitle = 'C'">
78	<a id="library-index" name="library-index"/>
79	<xsl:call-template name="gentext">
80	<xsl:with-param name="key">Libraries</xsl:with-param>
81	</xsl:call-template>
82	</xsl:when>
83	<xsl:when test="$divtitle = 'D'">
84	<xsl:choose>
85	<xsl:when test="$book-type = 'blfs'">
86	<a id="kernel-config-index" name="kernel-config-index"/>
87	<xsl:call-template name="gentext">
88	<xsl:with-param name="key">Kernel Configuration</xsl:with-param>
89	</xsl:call-template>
90	</xsl:when>
91	<xsl:otherwise>
92	<a id="scripts-index" name="scripts-index"/>
93	<xsl:call-template name="gentext">
94	<xsl:with-param name="key">Scripts</xsl:with-param>
95	</xsl:call-template>
96	</xsl:otherwise>
97	</xsl:choose>
98	</xsl:when>
99	<xsl:when test="$divtitle = 'E'">
100	<xsl:choose>
101	<xsl:when test="$book-type = 'blfs'">
102	<a id="config-file-index" name="config-file-index"/>
103	<xsl:call-template name="gentext">
104	<xsl:with-param name="key">Configuration Files</xsl:with-param>
105	</xsl:call-template>
106	</xsl:when>
107	<xsl:otherwise>
108	<a id="other-index" name="other-index"/>
109	<xsl:call-template name="gentext">
110	<xsl:with-param name="key">Others</xsl:with-param>
111	</xsl:call-template>
112	</xsl:otherwise>
113	</xsl:choose>
114	</xsl:when>
115	<xsl:when test="$divtitle = 'F'">
116	<a id="bootscript-index" name="bootscript-index"/>
117	<xsl:call-template name="gentext">
118	<xsl:with-param name="key">Bootscripts</xsl:with-param>
119	</xsl:call-template>
120	</xsl:when>
121	<xsl:when test="$divtitle = 'G'">
122	<a id="other-index" name="other-index"/>
123	<xsl:call-template name="gentext">
124	<xsl:with-param name="key">Others</xsl:with-param>
125	</xsl:call-template>
126	</xsl:when>
127	<xsl:otherwise>
128	<xsl:value-of select="$divtitle"/>
129	</xsl:otherwise>
130	</xsl:choose>
131	</h2>
132	</xsl:if>
133	<ul>
134	<xsl:apply-templates select="key('letter', $key)[&scope;] [count(.\|key('primary', &primary;)[&scope;][1])=1]"
135	mode="index-primary">
136	<xsl:with-param name="scope" select="$scope"/>
137	<xsl:sort select="translate(&primary;, &lowercase;, &uppercase;)"/>
138	</xsl:apply-templates>
139	</ul>
140	</xsl:if>
141	</xsl:template>
142
143	<!-- Dropping $term.separator and $number.separator from here.
144	We add our customized ones in the output flow.
145	As all our indexterm have @zone attributes, removed a lot of
146	unused code. -->
147	<!-- The original template is in {docbook-xsl}/xhtml/autoidx.xsl -->
148	<xsl:template match="indexterm" mode="reference">
149	<xsl:param name="scope" select="."/>
150	<xsl:call-template name="reference">
151	<xsl:with-param name="zones" select="normalize-space(@zone)"/>
152	<xsl:with-param name="scope" select="$scope"/>
153	</xsl:call-template>
154	</xsl:template>
155
156	<!-- Primary items:
157	Changed the output format from dl to ul.
158	Placed the term and separator into strong tags.
159	Placed the target links into a div.
160	Removed code for unused see and sealso childs. -->
161	<!-- The original template is in {docbook-xsl}/xhtml/autoidx.xsl -->
162	<xsl:template match="indexterm" mode="index-primary">
163	<xsl:param name="scope" select="."/>
164	<xsl:variable name="key" select="&primary;"/>
165	<xsl:variable name="refs" select="key('primary', $key)[&scope;]"/>
166	<li>
167	<strong class="item">
168	<xsl:value-of select="primary"/>
169	<xsl:text>: </xsl:text>
170	</strong>
171	<span class='indexref'>
172	<xsl:for-each select="$refs[generate-id() = generate-id(key('primary-section',concat($key, &sep;, &section.id;))[&scope;][1])]">
173	<xsl:apply-templates select="." mode="reference">
174	<xsl:with-param name="scope" select="$scope"/>
175	</xsl:apply-templates>
176	</xsl:for-each>
177	</span>
178	<xsl:if test="$refs/secondary">
179	<ul>
180	<xsl:apply-templates select="$refs[secondary and count(.\|key('secondary', concat($key, &sep;, &secondary;))[&scope;][1]) = 1]"
181	mode="index-secondary">
182	<xsl:with-param name="scope" select="$scope"/>
183	<xsl:sort select="translate(&secondary;, &lowercase;, &uppercase;)"/>
184	</xsl:apply-templates>
185	</ul>
186	</xsl:if>
187	</li>
188	</xsl:template>
189
190	<!-- Secondary items:
191	Changed the output format from dl to ul.
192	Placed the term and separator into strong tags.
193	Placed the target links into a div.
194	Removed code for unused tertiary, see, and sealso childs. -->
195	<!-- The original template is in {docbook-xsl}/xhtml/autoidx.xsl -->
196	<xsl:template match="indexterm" mode="index-secondary">
197	<xsl:param name="scope" select="."/>
198	<xsl:variable name="key" select="concat(&primary;, &sep;, &secondary;)"/>
199	<xsl:variable name="refs" select="key('secondary', $key)[&scope;]"/>
200	<li>
201	<strong class="secitem">
202	<xsl:value-of select="secondary"/>
203	<xsl:text>: </xsl:text>
204	</strong>
205	<span class='indexref'>
206	<xsl:for-each select="$refs[generate-id() = generate-id(key('secondary-section', concat($key, &sep;, &section.id;))[&scope;][1])]">
207	<xsl:apply-templates select="." mode="reference">
208	<xsl:with-param name="scope" select="$scope"/>
209	</xsl:apply-templates>
210	</xsl:for-each>
211	</span>
212	</li>
213	</xsl:template>
214
215	<!-- The target links:
216	Changed links separator.
217	On the second @zone link, we use a fixed string for the text
218	with gentext support.
219	Assume that there is no more than 2 @zone in a indexterm.
220	Use href.target.uri named template to resolve the links. It is faster
221	than the default href.target named template. -->
222	<!-- The original template is in {docbook-xsl}/xhtml/autoidx.xsl -->
223	<xsl:template name="reference">
224	<xsl:param name="scope" select="."/>
225	<xsl:param name="zones"/>
226	<xsl:choose>
227	<xsl:when test="contains($zones, ' ')">
228	<xsl:variable name="zone" select="substring-before($zones, ' ')"/>
229	<xsl:variable name="zone2" select="substring-after($zones, ' ')"/>
230	<xsl:variable name="target" select="key('sections', $zone)[&scope;]"/>
231	<xsl:variable name="target2" select="key('sections', $zone2)[&scope;]"/>
232	<a>
233	<xsl:attribute name="href">
234	<xsl:call-template name="href.target.uri">
235	<xsl:with-param name="object" select="$target[1]"/>
236	</xsl:call-template>
237	</xsl:attribute>
238	<xsl:apply-templates select="$target[1]" mode="index-title-content"/>
239	</a>
240	<xsl:text> -- </xsl:text>
241	<a>
242	<xsl:attribute name="href">
243	<xsl:call-template name="href.target.uri">
244	<xsl:with-param name="object" select="$target2[1]"/>
245	</xsl:call-template>
246	</xsl:attribute>
247	<xsl:call-template name="gentext">
248	<xsl:with-param name="key">description</xsl:with-param>
249	</xsl:call-template>
250	</a>
251	<br/>
252	</xsl:when>
253	<xsl:otherwise>
254	<xsl:variable name="zone" select="$zones"/>
255	<xsl:variable name="target" select="key('sections', $zone)[&scope;]"/>
256	<a>
257	<xsl:attribute name="href">
258	<xsl:call-template name="href.target.uri">
259	<xsl:with-param name="object" select="$target[1]"/>
260	</xsl:call-template>
261	</xsl:attribute>
262	<xsl:apply-templates select="$target[1]" mode="index-title-content"/>
263	</a>
264	</xsl:otherwise>
265	</xsl:choose>
266	</xsl:template>
267
268	</xsl:stylesheet>

Note: See TracBrowser for help on using the repository browser.

Download in other formats: