source: BOOK/stylesheets/lfs-xsl/docbook-xsl-snapshot/fo/refentry.xsl@ 902b794

clfs-1.2 clfs-2.1 clfs-3.0.0-systemd clfs-3.0.0-sysvinit systemd sysvinit
Last change on this file since 902b794 was f8c4e94, checked in by Manuel Canales Esparcia <manuel@…>, 17 years ago

Added LFS XSL Stylesheets.
  • Property mode set to 100644
File size: 23.6 KB
Line 
1<?xml version='1.0'?>
2<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
3 xmlns:fo="http://www.w3.org/1999/XSL/Format"
4 xmlns:axf="http://www.antennahouse.com/names/XSL/Extensions"
5 version='1.0'>
6
7<!-- ********************************************************************
8 $Id$
9 ********************************************************************
10
11 This file is part of the XSL DocBook Stylesheet distribution.
12 See ../README or http://docbook.sf.net/release/xsl/current/ for
13 copyright and other information.
14
15 ******************************************************************** -->
16
17<!-- ==================================================================== -->
18
19<xsl:template match="reference">
20 <xsl:if test="not(partintro)">
21 <xsl:variable name="id">
22 <xsl:call-template name="object.id"/>
23 </xsl:variable>
24 <xsl:variable name="master-reference">
25 <xsl:call-template name="select.pagemaster"/>
26 </xsl:variable>
27
28 <fo:page-sequence hyphenate="{$hyphenate}"
29 master-reference="{$master-reference}">
30 <xsl:attribute name="language">
31 <xsl:call-template name="l10n.language"/>
32 </xsl:attribute>
33 <xsl:attribute name="format">
34 <xsl:call-template name="page.number.format">
35 <xsl:with-param name="master-reference" select="$master-reference"/>
36 </xsl:call-template>
37 </xsl:attribute>
38
39 <xsl:attribute name="initial-page-number">
40 <xsl:call-template name="initial.page.number">
41 <xsl:with-param name="master-reference" select="$master-reference"/>
42 </xsl:call-template>
43 </xsl:attribute>
44
45 <xsl:attribute name="force-page-count">
46 <xsl:call-template name="force.page.count">
47 <xsl:with-param name="master-reference" select="$master-reference"/>
48 </xsl:call-template>
49 </xsl:attribute>
50
51 <xsl:attribute name="hyphenation-character">
52 <xsl:call-template name="gentext">
53 <xsl:with-param name="key" select="'hyphenation-character'"/>
54 </xsl:call-template>
55 </xsl:attribute>
56 <xsl:attribute name="hyphenation-push-character-count">
57 <xsl:call-template name="gentext">
58 <xsl:with-param name="key" select="'hyphenation-push-character-count'"/>
59 </xsl:call-template>
60 </xsl:attribute>
61 <xsl:attribute name="hyphenation-remain-character-count">
62 <xsl:call-template name="gentext">
63 <xsl:with-param name="key" select="'hyphenation-remain-character-count'"/>
64 </xsl:call-template>
65 </xsl:attribute>
66
67 <xsl:apply-templates select="." mode="running.head.mode">
68 <xsl:with-param name="master-reference" select="$master-reference"/>
69 </xsl:apply-templates>
70 <xsl:apply-templates select="." mode="running.foot.mode">
71 <xsl:with-param name="master-reference" select="$master-reference"/>
72 </xsl:apply-templates>
73
74 <fo:flow flow-name="xsl-region-body">
75 <xsl:call-template name="set.flow.properties">
76 <xsl:with-param name="element" select="local-name(.)"/>
77 <xsl:with-param name="master-reference" select="$master-reference"/>
78 </xsl:call-template>
79
80 <fo:block id="{$id}">
81 <xsl:call-template name="reference.titlepage"/>
82 </fo:block>
83 <!-- Create one page sequence if no pagebreaks needed -->
84 <xsl:if test="$refentry.pagebreak = 0">
85 <xsl:apply-templates select="refentry"/>
86 </xsl:if>
87 </fo:flow>
88 </fo:page-sequence>
89 </xsl:if>
90 <xsl:apply-templates select="partintro"/>
91 <xsl:if test="$refentry.pagebreak != 0">
92 <xsl:apply-templates select="refentry"/>
93 </xsl:if>
94</xsl:template>
95
96<xsl:template match="reference" mode="reference.titlepage.mode">
97 <xsl:call-template name="reference.titlepage"/>
98</xsl:template>
99
100<xsl:template match="reference/partintro">
101 <xsl:variable name="id">
102 <xsl:call-template name="object.id">
103 <xsl:with-param name="object" select="ancestor::reference"/>
104 </xsl:call-template>
105 </xsl:variable>
106 <xsl:variable name="master-reference">
107 <xsl:call-template name="select.pagemaster"/>
108 </xsl:variable>
109
110 <fo:page-sequence hyphenate="{$hyphenate}"
111 master-reference="{$master-reference}">
112 <xsl:attribute name="language">
113 <xsl:call-template name="l10n.language"/>
114 </xsl:attribute>
115 <xsl:attribute name="format">
116 <xsl:call-template name="page.number.format">
117 <xsl:with-param name="master-reference" select="$master-reference"/>
118 </xsl:call-template>
119 </xsl:attribute>
120
121 <xsl:attribute name="initial-page-number">
122 <xsl:call-template name="initial.page.number">
123 <xsl:with-param name="master-reference" select="$master-reference"/>
124 </xsl:call-template>
125 </xsl:attribute>
126
127 <xsl:attribute name="force-page-count">
128 <xsl:call-template name="force.page.count">
129 <xsl:with-param name="master-reference" select="$master-reference"/>
130 </xsl:call-template>
131 </xsl:attribute>
132
133 <xsl:attribute name="hyphenation-character">
134 <xsl:call-template name="gentext">
135 <xsl:with-param name="key" select="'hyphenation-character'"/>
136 </xsl:call-template>
137 </xsl:attribute>
138 <xsl:attribute name="hyphenation-push-character-count">
139 <xsl:call-template name="gentext">
140 <xsl:with-param name="key" select="'hyphenation-push-character-count'"/>
141 </xsl:call-template>
142 </xsl:attribute>
143 <xsl:attribute name="hyphenation-remain-character-count">
144 <xsl:call-template name="gentext">
145 <xsl:with-param name="key" select="'hyphenation-remain-character-count'"/>
146 </xsl:call-template>
147 </xsl:attribute>
148
149 <xsl:apply-templates select="." mode="running.head.mode">
150 <xsl:with-param name="master-reference" select="$master-reference"/>
151 </xsl:apply-templates>
152 <xsl:apply-templates select="." mode="running.foot.mode">
153 <xsl:with-param name="master-reference" select="$master-reference"/>
154 </xsl:apply-templates>
155
156 <fo:flow flow-name="xsl-region-body">
157 <xsl:call-template name="set.flow.properties">
158 <xsl:with-param name="element" select="local-name(.)"/>
159 <xsl:with-param name="master-reference" select="$master-reference"/>
160 </xsl:call-template>
161 <fo:block id="{$id}">
162 <xsl:apply-templates select=".." mode="reference.titlepage.mode"/>
163 </fo:block>
164 <xsl:if test="title">
165 <xsl:call-template name="partintro.titlepage"/>
166 </xsl:if>
167 <xsl:apply-templates/>
168 <!-- Create one page sequence if no pagebreaks needed -->
169 <xsl:if test="$refentry.pagebreak = 0">
170 <xsl:apply-templates select="../refentry"/>
171 </xsl:if>
172 </fo:flow>
173 </fo:page-sequence>
174</xsl:template>
175
176<xsl:template match="reference/docinfo|refentry/refentryinfo"></xsl:template>
177<xsl:template match="reference/info"></xsl:template>
178<xsl:template match="reference/title"></xsl:template>
179<xsl:template match="reference/subtitle"></xsl:template>
180
181<!-- ==================================================================== -->
182
183<xsl:template match="refentry">
184 <xsl:variable name="id">
185 <xsl:call-template name="object.id"/>
186 </xsl:variable>
187
188 <xsl:variable name="master-reference">
189 <xsl:call-template name="select.pagemaster"/>
190 </xsl:variable>
191
192 <xsl:variable name="refentry.content">
193 <fo:block id="{$id}">
194 <xsl:apply-templates/>
195 </fo:block>
196 </xsl:variable>
197
198 <xsl:choose>
199 <xsl:when test="not(parent::*) or
200 (parent::reference and $refentry.pagebreak != 0) or
201 parent::part">
202 <!-- make a page sequence -->
203 <fo:page-sequence hyphenate="{$hyphenate}"
204 master-reference="{$master-reference}">
205 <xsl:attribute name="language">
206 <xsl:call-template name="l10n.language"/>
207 </xsl:attribute>
208 <xsl:attribute name="format">
209 <xsl:call-template name="page.number.format">
210 <xsl:with-param name="master-reference" select="$master-reference"/>
211 </xsl:call-template>
212 </xsl:attribute>
213
214 <xsl:attribute name="initial-page-number">
215 <xsl:call-template name="initial.page.number">
216 <xsl:with-param name="master-reference" select="$master-reference"/>
217 </xsl:call-template>
218 </xsl:attribute>
219
220 <xsl:attribute name="force-page-count">
221 <xsl:call-template name="force.page.count">
222 <xsl:with-param name="master-reference" select="$master-reference"/>
223 </xsl:call-template>
224 </xsl:attribute>
225
226 <xsl:attribute name="hyphenation-character">
227 <xsl:call-template name="gentext">
228 <xsl:with-param name="key" select="'hyphenation-character'"/>
229 </xsl:call-template>
230 </xsl:attribute>
231 <xsl:attribute name="hyphenation-push-character-count">
232 <xsl:call-template name="gentext">
233 <xsl:with-param name="key" select="'hyphenation-push-character-count'"/>
234 </xsl:call-template>
235 </xsl:attribute>
236 <xsl:attribute name="hyphenation-remain-character-count">
237 <xsl:call-template name="gentext">
238 <xsl:with-param name="key" select="'hyphenation-remain-character-count'"/>
239 </xsl:call-template>
240 </xsl:attribute>
241
242 <xsl:apply-templates select="." mode="running.head.mode">
243 <xsl:with-param name="master-reference" select="$master-reference"/>
244 </xsl:apply-templates>
245 <xsl:apply-templates select="." mode="running.foot.mode">
246 <xsl:with-param name="master-reference" select="$master-reference"/>
247 </xsl:apply-templates>
248
249 <fo:flow flow-name="xsl-region-body">
250 <xsl:call-template name="set.flow.properties">
251 <xsl:with-param name="element" select="local-name(.)"/>
252 <xsl:with-param name="master-reference" select="$master-reference"/>
253 </xsl:call-template>
254
255 <xsl:copy-of select="$refentry.content"/>
256 </fo:flow>
257 </fo:page-sequence>
258 </xsl:when>
259 <xsl:otherwise>
260 <fo:block>
261 <xsl:if test="$refentry.pagebreak != 0">
262 <xsl:attribute name="break-before">page</xsl:attribute>
263 </xsl:if>
264 <xsl:copy-of select="$refentry.content"/>
265 </fo:block>
266 </xsl:otherwise>
267 </xsl:choose>
268</xsl:template>
269
270<xsl:template match="refmeta">
271</xsl:template>
272
273<xsl:template match="manvolnum">
274 <xsl:if test="$refentry.xref.manvolnum != 0">
275 <xsl:text>(</xsl:text>
276 <xsl:apply-templates/>
277 <xsl:text>)</xsl:text>
278 </xsl:if>
279</xsl:template>
280
281<xsl:template match="refmiscinfo">
282</xsl:template>
283
284<xsl:template match="refentrytitle">
285 <xsl:call-template name="inline.charseq"/>
286</xsl:template>
287
288<xsl:template match="refnamediv">
289 <xsl:variable name="id">
290 <xsl:call-template name="object.id"/>
291 </xsl:variable>
292
293 <fo:block id="{$id}">
294
295 <!-- if refentry.generate.name is non-zero, then we need to generate a -->
296 <!-- localized "Name" subheading for this refnamdiv (unless it has a -->
297 <!-- preceding sibling that is a refnamediv, in which case we have already -->
298 <!-- generated a "Name" subheading, so we don't need to do it again -->
299 <xsl:if test="$refentry.generate.name != 0">
300 <xsl:choose>
301 <xsl:when test="preceding-sibling::refnamediv">
302 <!-- no generated title on secondary refnamedivs! -->
303 </xsl:when>
304 <xsl:otherwise>
305 <fo:block xmlns:fo="http://www.w3.org/1999/XSL/Format"
306 xsl:use-attribute-sets="refnamediv.titlepage.recto.style"
307 font-family="{$title.fontset}">
308 <!-- Contents of what is now the format.refentry.subheading -->
309 <!-- template were formerly intended to be used only to -->
310 <!-- process those subsections of Refentry that have "real" -->
311 <!-- title children. So as a kludge to get around the fact -->
312 <!-- that the template still basically "expects" to be -->
313 <!-- processing that kind of a node, when we call the -->
314 <!-- template to process generated titles, we must call it -->
315 <!-- with values for the "offset" and "section" parameters -->
316 <!-- that are different from the default values in the -->
317 <!-- format.refentry.subheading template itself. Because -->
318 <!-- those defaults are the values appropriate for processing -->
319 <!-- "real" title nodes. -->
320 <xsl:call-template name="format.refentry.subheading">
321 <xsl:with-param name="section" select="self::*"/>
322 <xsl:with-param name="offset" select="1"/>
323 <xsl:with-param name="gentext.key" select="'RefName'"/>
324 </xsl:call-template>
325 </fo:block>
326 </xsl:otherwise>
327 </xsl:choose>
328 </xsl:if>
329
330 <xsl:if test="$refentry.generate.title != 0">
331 <xsl:variable name="section.level">
332 <xsl:call-template name="refentry.level">
333 <xsl:with-param name="node" select="ancestor::refentry"/>
334 </xsl:call-template>
335 </xsl:variable>
336
337 <xsl:variable name="reftitle">
338 <xsl:choose>
339 <xsl:when test="../refmeta/refentrytitle">
340 <xsl:apply-templates select="../refmeta/refentrytitle"/>
341 </xsl:when>
342 <xsl:otherwise>
343 <xsl:apply-templates select="refname[1]"/>
344 </xsl:otherwise>
345 </xsl:choose>
346 </xsl:variable>
347
348 <!-- xsl:use-attribute-sets takes only a Qname, not a variable -->
349 <xsl:choose>
350 <xsl:when test="preceding-sibling::refnamediv">
351 <!-- no title on secondary refnamedivs! -->
352 </xsl:when>
353 <xsl:when test="$section.level = 1">
354 <fo:block xsl:use-attribute-sets="refentry.title.properties">
355 <fo:block xsl:use-attribute-sets="section.title.level1.properties">
356 <xsl:value-of select="$reftitle"/>
357 </fo:block>
358 </fo:block>
359 </xsl:when>
360 <xsl:when test="$section.level = 2">
361 <fo:block xsl:use-attribute-sets="refentry.title.properties">
362 <fo:block xsl:use-attribute-sets="section.title.level2.properties">
363 <xsl:value-of select="$reftitle"/>
364 </fo:block>
365 </fo:block>
366 </xsl:when>
367 <xsl:when test="$section.level = 3">
368 <fo:block xsl:use-attribute-sets="refentry.title.properties">
369 <fo:block xsl:use-attribute-sets="section.title.level3.properties">
370 <xsl:value-of select="$reftitle"/>
371 </fo:block>
372 </fo:block>
373 </xsl:when>
374 <xsl:when test="$section.level = 4">
375 <fo:block xsl:use-attribute-sets="refentry.title.properties">
376 <fo:block xsl:use-attribute-sets="section.title.level4.properties">
377 <xsl:value-of select="$reftitle"/>
378 </fo:block>
379 </fo:block>
380 </xsl:when>
381 <xsl:when test="$section.level = 5">
382 <fo:block xsl:use-attribute-sets="refentry.title.properties">
383 <fo:block xsl:use-attribute-sets="section.title.level5.properties">
384 <xsl:value-of select="$reftitle"/>
385 </fo:block>
386 </fo:block>
387 </xsl:when>
388 <xsl:otherwise>
389 <fo:block xsl:use-attribute-sets="refentry.title.properties">
390 <fo:block xsl:use-attribute-sets="section.title.level6.properties">
391 <xsl:value-of select="$reftitle"/>
392 </fo:block>
393 </fo:block>
394 </xsl:otherwise>
395 </xsl:choose>
396 </xsl:if>
397
398 <fo:block>
399 <xsl:if test="not(following-sibling::refnamediv)">
400 <xsl:attribute name="space-after">1em</xsl:attribute>
401 </xsl:if>
402 <xsl:apply-templates/>
403 </fo:block>
404 </fo:block>
405</xsl:template>
406
407<xsl:template match="refname">
408 <xsl:if test="not(preceding-sibling::refdescriptor)">
409 <xsl:apply-templates/>
410 <xsl:if test="following-sibling::refname">
411 <xsl:text>, </xsl:text>
412 </xsl:if>
413 </xsl:if>
414</xsl:template>
415
416<xsl:template match="refpurpose">
417 <xsl:if test="node()">
418 <xsl:text> </xsl:text>
419 <xsl:call-template name="dingbat">
420 <xsl:with-param name="dingbat">em-dash</xsl:with-param>
421 </xsl:call-template>
422 <xsl:text> </xsl:text>
423 <xsl:apply-templates/>
424 </xsl:if>
425</xsl:template>
426
427<xsl:template match="refdescriptor">
428 <xsl:apply-templates/>
429</xsl:template>
430
431<xsl:template match="refclass">
432 <xsl:if test="$refclass.suppress = 0">
433 <fo:block font-weight="bold">
434 <xsl:if test="@role">
435 <xsl:value-of select="@role"/>
436 <xsl:text>: </xsl:text>
437 </xsl:if>
438 <xsl:apply-templates/>
439 </fo:block>
440 </xsl:if>
441</xsl:template>
442
443<xsl:template match="refsynopsisdiv">
444 <xsl:variable name="id">
445 <xsl:call-template name="object.id"/>
446 </xsl:variable>
447
448 <fo:block id="{$id}">
449 <xsl:if test="not(refsynopsisdivinfo/title|docinfo/title|info/title|title)">
450 <!-- * if we there is no appropriate title for this Refsynopsisdiv, -->
451 <!-- * then we need to call format.refentry.subheading to generate one -->
452 <fo:block xmlns:fo="http://www.w3.org/1999/XSL/Format"
453 xsl:use-attribute-sets="refsynopsisdiv.titlepage.recto.style"
454 font-family="{$title.fontset}">
455 <!-- Contents of what is now the format.refentry.subheading -->
456 <!-- template were formerly intended to be used only to -->
457 <!-- process those subsections of Refentry that have "real" -->
458 <!-- title children. So as a kludge to get around the fact -->
459 <!-- that the template still basically "expects" to be -->
460 <!-- processing that kind of a node, when we call the -->
461 <!-- template to process generated titles, we must call it -->
462 <!-- with values for the "offset" and "section" parameters -->
463 <!-- that are different from the default values in the -->
464 <!-- format.refentry.subheading template itself. Because -->
465 <!-- those defaults are the values appropriate for processing -->
466 <!-- "real" title nodes. -->
467 <xsl:call-template name="format.refentry.subheading">
468 <xsl:with-param name="section" select="parent::*"/>
469 <xsl:with-param name="offset" select="1"/>
470 <xsl:with-param name="gentext.key" select="'RefSynopsisDiv'"/>
471 </xsl:call-template>
472 </fo:block>
473 </xsl:if>
474 <xsl:call-template name="refsynopsisdiv.titlepage"/>
475 <xsl:apply-templates/>
476 </fo:block>
477</xsl:template>
478
479<xsl:template match="refsection">
480 <xsl:variable name="id">
481 <xsl:call-template name="object.id"/>
482 </xsl:variable>
483
484 <fo:block id="{$id}">
485 <xsl:call-template name="refsection.titlepage"/>
486 <xsl:apply-templates/>
487 </fo:block>
488</xsl:template>
489
490<xsl:template match="refsect1">
491 <xsl:variable name="id">
492 <xsl:call-template name="object.id"/>
493 </xsl:variable>
494
495 <fo:block id="{$id}">
496 <xsl:call-template name="refsect1.titlepage"/>
497 <xsl:apply-templates/>
498 </fo:block>
499</xsl:template>
500
501<xsl:template match="refsect2">
502 <xsl:variable name="id">
503 <xsl:call-template name="object.id"/>
504 </xsl:variable>
505
506 <fo:block id="{$id}">
507 <xsl:call-template name="refsect2.titlepage"/>
508 <xsl:apply-templates/>
509 </fo:block>
510</xsl:template>
511
512<xsl:template match="refsect3">
513 <xsl:variable name="id">
514 <xsl:call-template name="object.id"/>
515 </xsl:variable>
516
517 <fo:block id="{$id}">
518 <xsl:call-template name="refsect3.titlepage"/>
519 <xsl:apply-templates/>
520 </fo:block>
521</xsl:template>
522
523<xsl:template match="refsynopsisdiv/title
524 |refsection/title
525 |refsect1/title
526 |refsect2/title
527 |refsect3/title">
528 <!-- nop; titlepage.mode instead -->
529</xsl:template>
530
531<xsl:template match="refsynopsisdiv/title
532 |refsection/title
533 |refsect1/title
534 |refsect2/title
535 |refsect3/title
536 |refsynopsisdiv/info/title
537 |refsection/info/title
538 |refsect1/info/title
539 |refsect2/info/title
540 |refsect3/info/title"
541 mode="titlepage.mode"
542 priority="2">
543 <xsl:call-template name="format.refentry.subheading"/>
544</xsl:template>
545
546<xsl:template name="format.refentry.subheading">
547<!-- This template is now called to process generated titles for -->
548<!-- Refnamediv and Refsynopsisdiv, as well as "real" titles for -->
549<!-- Refsynopsisdiv, Refsection, and Refsect[1-3]. -->
550<!-- -->
551<!-- But the contents of this template were formerly intended to be used -->
552<!-- only to process those subsections of Refentry that have "real" title -->
553<!-- children. So as a kludge to get around the fact that the template -->
554<!-- still basically "expects" to be processing that kind of a node, the -->
555<!-- "offset" parameter was added and the "section" variable was changed to -->
556<!-- a parameter so that when called for a generated title on a Refnamediv -->
557<!-- or Refsynopsisdiv, we can call it like this: -->
558<!-- -->
559<!-- <xsl:call-template name="format.refentry.subheading"> -->
560<!-- <xsl:with-param name="section" select="self::*"/> -->
561<!-- <xsl:with-param name="offset" select="1"/> -->
562<!-- <xsl:with-param name="gentext.key" select="'RefName'"/> -->
563<!-- </xsl:call-template> -->
564<!-- -->
565 <xsl:param name="section"
566 select="(ancestor::refsynopsysdiv
567 |ancestor::refsection
568 |ancestor::refsect1
569 |ancestor::refsect2
570 |ancestor::refsect3)[last()]"/>
571 <xsl:param name="offset" select="0"/>
572 <xsl:param name="gentext.key"/>
573
574 <fo:block keep-with-next.within-column="always">
575 <xsl:variable name="id">
576 <xsl:call-template name="object.id">
577 <xsl:with-param name="object" select="$section"/>
578 </xsl:call-template>
579 </xsl:variable>
580
581 <xsl:variable name="level">
582 <xsl:call-template name="section.level">
583 <xsl:with-param name="node" select="$section"/>
584 </xsl:call-template>
585 </xsl:variable>
586
587 <xsl:variable name="title">
588 <!-- If we have a non-empty value for the $gentext.key param, then we -->
589 <!-- generate an appropriate title here. Otherwise, we have a real -->
590 <!-- title child, so we copy contents of that to the result tree. -->
591 <xsl:choose>
592 <xsl:when test="$gentext.key != ''">
593 <xsl:call-template name="gentext">
594 <xsl:with-param name="key" select="$gentext.key"/>
595 </xsl:call-template>
596 </xsl:when>
597 <xsl:otherwise>
598 <xsl:apply-templates select="$section" mode="object.title.markup">
599 <xsl:with-param name="allow-anchors" select="1"/>
600 </xsl:apply-templates>
601 </xsl:otherwise>
602 </xsl:choose>
603 </xsl:variable>
604
605 <xsl:if test="$passivetex.extensions != 0">
606 <fotex:bookmark xmlns:fotex="http://www.tug.org/fotex"
607 fotex-bookmark-level="{$level + 2 + $offset}"
608 fotex-bookmark-label="{$id}">
609 <xsl:value-of select="$title"/>
610 </fotex:bookmark>
611 </xsl:if>
612
613 <xsl:if test="$axf.extensions != 0">
614 <xsl:attribute name="axf:outline-level">
615 <xsl:value-of select="count(ancestor::*)-1 + $offset"/>
616 </xsl:attribute>
617 <xsl:attribute name="axf:outline-expand">false</xsl:attribute>
618 <xsl:attribute name="axf:outline-title">
619 <xsl:value-of select="$title"/>
620 </xsl:attribute>
621 </xsl:if>
622
623 <xsl:call-template name="section.heading">
624 <xsl:with-param name="level" select="$level + $offset"/>
625 <xsl:with-param name="title" select="$title"/>
626 </xsl:call-template>
627 </fo:block>
628</xsl:template>
629
630<xsl:template match="refsectioninfo|refsection/info"></xsl:template>
631<xsl:template match="refsect1info|refsect1/info"></xsl:template>
632<xsl:template match="refsect2info|refsect2/info"></xsl:template>
633<xsl:template match="refsect3info|refsect3/info"></xsl:template>
634
635<!-- ==================================================================== -->
636
637</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.